Compile with /MT instead of /MD using CMake

Cmake Problem Overview

I'm using CMake on windows with the Windows SDK and NMake Makefiles.

By default it compiles with the /MD compiler switch.

How can I change it to compile with the /MT switch instead?

Cmake Solutions

Solution 1 - Cmake

You can modify the CMAKE_CXX_FLAGS_<Build Type> and/or CMAKE_C_FLAGS_<Build Type> variables:

set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

If your CMake flags already contain /MD, you can ensure that the above commands are executed after the point at which /MD is inserted (the later addition of /MT overrides the conflicting existing option), or you can set the flags from scratch:

set(CMAKE_CXX_FLAGS_RELEASE "/MT")
set(CMAKE_CXX_FLAGS_DEBUG "/MTd")

Or alternatively, you could replace the existing /MD and /MDd values with /MT and /MTd respectively by doing something like:

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        )
foreach(CompilerFlag ${CompilerFlags})
  string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
endforeach()

Solution 2 - Cmake

CMake finally added proper support for this in version 3.15 with the MSVC_RUNTIME_LIBRARY target property:

cmake_minimum_required(VERSION 3.15)
cmake_policy(SET CMP0091 NEW)
project(my_project)

add_executable(foo foo.c)
set_property(TARGET foo PROPERTY
             MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

You can also specify a global default by setting the CMAKE_MSVC_RUNTIME_LIBRARY variable instead.

Solution 3 - Cmake

It seems that for Visual Studio 15 2017 and CMake 3.12 the way to replace /MD by /MT is by adding this snippet to the CMakeLists.txt file:

if(MSVC)
    add_compile_options(
        $<$<CONFIG:>:/MT> #---------|
        $<$<CONFIG:Debug>:/MTd> #---|-- Statically link the runtime libraries
        $<$<CONFIG:Release>:/MT> #--|
    )
endif()

I found this solution in the official CMake repository: https://gitlab.kitware.com/cmake/cmake/issues/18390

Solution 4 - Cmake

Check out ucm_set_runtime - this macro will replace the flags for static or dynamic runtime - to see the effects, use ucm_print_flags (also checkout this Stack Overflow question).

Solution 5 - Cmake

I have to use set( ... CACHE ... FORCE) to overwrite MSVC's default cache.

If I do not use this method, MSVC still outputs /MD options.

set(CompilerFlags
		CMAKE_CXX_FLAGS
		CMAKE_CXX_FLAGS_DEBUG
		CMAKE_CXX_FLAGS_RELEASE
		CMAKE_CXX_FLAGS_MINSIZEREL
		CMAKE_CXX_FLAGS_RELWITHDEBINFO
		CMAKE_C_FLAGS
		CMAKE_C_FLAGS_DEBUG
		CMAKE_C_FLAGS_RELEASE
		CMAKE_C_FLAGS_MINSIZEREL
		CMAKE_C_FLAGS_RELWITHDEBINFO
		)
foreach(CompilerFlag ${CompilerFlags})
	string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
	set(${CompilerFlag} "${${CompilerFlag}}" CACHE STRING "msvc compiler flags" FORCE)
	message("MSVC flags: ${CompilerFlag}:${${CompilerFlag}}")
endforeach()

Solution 6 - Cmake

Since cmacke 3.15, you can use MSVC_RUNTIME_LIBRARY. See https://cmake.org/cmake/help/latest/prop_tgt/MSVC_RUNTIME_LIBRARY.html

Content Type	Original Author	Original Content on Stackoverflow
Question	Josh	View Question on Stackoverflow
Solution 1 - Cmake	Fraser	View Answer on Stackoverflow
Solution 2 - Cmake	ComicSansMS	View Answer on Stackoverflow
Solution 3 - Cmake	Carlos D. Álvaro	View Answer on Stackoverflow
Solution 4 - Cmake	onqtam	View Answer on Stackoverflow
Solution 5 - Cmake	shawn	View Answer on Stackoverflow
Solution 6 - Cmake	Mohamed Oulmahdi	View Answer on Stackoverflow